Forum@DeGiorgi :: Pogledajte temu - Šuplja kugla u Mathematici?

through

[^/[Print]\]

Forum@DeGiorgi -> Čistilište

#1: Šuplja kugla u Mathematici? Autor/ica: Luuka, Lokacija: Hakuna Matata

Postano: 13:28 sub, 5. 2. 2011
—
Trebala bi mi pomoć oko crtanja u Mathematici.

On što bi mi trebalo je nacrati šuplju kuglu sa unutrašnjim radijusom r1, vanjskim r2. Dakle za 0⇐r<r1 je prazno, pa za r1⇐r⇐r2 je puno.
Probao sam nešto sa ParametricPlot3d, ali nisam dobio što sam htio.

Ovo imam zasad:

Kod:

prva = ParametricPlot3D[
{0.5*Cos[\[Phi]] Sin[\[Theta]], 0.5*Sin[\[Phi]] Sin[\[Theta]],
0.5*Cos[\[Theta]]}, {\[Phi], 0, 2 Pi}, {\[Theta], 0, Pi},
Mesh -> False]
druga = ParametricPlot3D[
{Cos[\[Phi]] Sin[\[Theta]], Sin[\[Phi]] Sin[\[Theta]],
Cos[\[Theta]]}, {\[Phi], 0, 3 Pi/2}, {\[Theta], 0, Pi},
Mesh -> False]
Show[{druga, prva}, Axes -> False]

To mi je početni položaj, i to bi valjda trebalo bit jednostavno. Nakon tog crteža mi treba još jedan. S tom kuglom se nešto desi i ona se deformira. Pomak ovisi samo o radijusu i dan je funkcijom u=u(r). Trebam nacrtati kuglu nakon te deformacije. Točka (x,y,z) prijeđe u (x,y,z)+u(r).

Hvala svima na pomoći Very Happy

#2: Autor/ica: vsego, Lokacija: /sbin/init

Postano: 14:56 sub, 5. 2. 2011
—
Ovo prvo bih izveo tako da nacrtam rubove:

Kod:

prva=ParametricPlot3D[{Cos[\[Phi]] Sin[\[Theta]],Sin[\[Phi]] Sin[\[Theta]],Cos[\[Theta]]},{\[Phi],0,3 Pi/2},{\[Theta],0,Pi},Mesh->False];
druga=ParametricPlot3D[0.5{Cos[\[Phi]] Sin[\[Theta]],Sin[\[Phi]] Sin[\[Theta]],Cos[\[Theta]]},{\[Phi],0,3 Pi/2},{\[Theta],0,Pi},Mesh->False];
treca=ParametricPlot3D[r {Sin[\[Theta]],0,Cos[\[Theta]]},{r,0.5,1},{\[Theta],0,Pi},Mesh->False];
cetvrta=ParametricPlot3D[r {0,- Sin[\[Theta]],Cos[\[Theta]]},{r,0.5,1},{\[Theta],0,Pi},Mesh->False];
sve=Show[{prva,druga,treca,cetvrta},Axes->False]

Za ovo drugo treba samo izmanipulirati racunanje tocaka. Jednostavno interaktivno isprobavanje mozes izvesti ovako:

Kod:

Manipulate[Show[{
ParametricPlot3D[{Cos[\[Phi]] Sin[\[Theta]]+ux,Sin[\[Phi]] Sin[\[Theta]]+uy,Cos[\[Theta]]+uz},{\[Phi],0,3 Pi/2},{\[Theta],0,Pi},Mesh->False],
ParametricPlot3D[0.5 {Cos[\[Phi]] Sin[\[Theta]]+ux,Sin[\[Phi]] Sin[\[Theta]]+uy,Cos[\[Theta]]+uz},{\[Phi],0,3 Pi/2},{\[Theta],0,Pi},Mesh->False],
ParametricPlot3D[r {Sin[\[Theta]]+ux,uy,Cos[\[Theta]]+uz},{r,0.5,1},{\[Theta],0,Pi},Mesh->False],
ParametricPlot3D[r {ux,-Sin[\[Theta]]+uy,Cos[\[Theta]]+uz},{r,0.5,1},{\[Theta],0,Pi},Mesh->False]
},Axes->False],
{{ux,0},-1,1},{{uy,0},-1,1},{{uz,0},-1,1}]

Nadam se da je to ono sto trazis ili barem korak u dobrom smjeru.

#3: Autor/ica: goranm,

Postano: 15:20 sub, 5. 2. 2011
—
Ne razumijem zašto crtati šuplju kuglu? Npr. sa

Kod:

RegionPlot3D[
1/4 < x^2 + y^2 + z^2 && x^2 + y^2 + z^2 <= 1, {x, -1, 0}, {y, -1,
1}, {z, -1, 0}, PlotRange->{{-1,1},{-1,1},{-1,1}}]

se postiže slično kao i prvi vsegin kod, a radijusom i komadom koji se odreže tako da se vidi unutrašnjost se lako manipulira. Odmah se ispričavam jer vjerojatno nisam dobro shvatio.

#4: Autor/ica: Luuka, Lokacija: Hakuna Matata

Postano: 15:52 sub, 5. 2. 2011
—
Oba odgovora će mi puno koristit, hvala obojici Thank you

Forum@DeGiorgi -> Čistilište

output generated using printer-friendly topic mod. Vremenska zona: GMT + 01:00.

Stranica 1 / 1.